Używanie funkcji JEŻELI z funkcjami ORAZ, LUB i NIE w programie Excel

W programie Excel funkcja JEŻELI umożliwia logiczne porównanie wartości z oczekiwanym wynikiem przez przetestowanie warunku i zwrócenie wyniku, jeśli ten warunek ma wartość Prawda lub Fałsz.

= JEŻELI (jakieś wyrażenie jest prawdziwe, to wykonaj określone działanie, a w przeciwnym razie wykonaj inne działanie)

Ale co zrobić, jeśli chcesz sprawdzić wiele warunków, z których wszystkie muszą mieć wartość Prawda lub Fałsz (ORAZ) bądź tylko jeden warunek powinien mieć wartość Prawda lub Fałsz (LUB) albo jeśli chcesz sprawdzić, czy warunek NIE spełnia kryteriów? Wszystkie 3 funkcje mogą być używane osobno, ale dużo częściej używa się ich razem z funkcjami JEŻELI.

Użyj funkcji JEŻELI wraz z funkcjami ORAZ, LUB i NIE, aby wykonać wiele obliczeń, czy warunki mają wartości Prawda, czy Fałsz.

Składnia

JEŻELI(ORAZ()) — JEŻELI(ORAZ(wartość_logiczna1; [wartość_logiczna2]; ...); wartość_jeżeli_prawda; [wartość_jeżeli_fałsz]))
JEŻELI(LUB()) — JEŻELI(LUB(wartość_logiczna1; [wartość_logiczna2]; ...); wartość_jeżeli_prawda; [wartość_jeżeli_fałsz]))
JEŻELI(NIE()) — JEŻELI(NIE(wartość_logiczna1); wartość_jeżeli_prawda; [wartość_jeżeli_fałsz]))


Nazwa argumentu	Opis
test_logiczny (wymagane)	Warunek, który ma zostać sprawdzony.
wartość_jeżeli_prawda (wymagane)	Wartość, która ma zostać zwrócona, jeśli wynik argumentu test_logiczny ma wartość PRAWDA.

wartość_jeżeli_fałsz (opcjonalne)	Wartość, która ma zostać zwrócona, jeśli wynik argumentu test_logiczny ma wartość FAŁSZ.

Oto informacje na temat indywidualnych struktur funkcji ORAZ, LUB i NIE. Po połączeniu każdej z nich z instrukcją JEŻELI wyglądają one następująco:

ORAZ — =JEŻELI(ORAZ(jakieś wyrażenie jest prawdziwe; jakieś inne wyrażenie jest prawdziwe); wartość jeśli prawda; wartość jeśli fałsz)
LUB — =JEŻELI(LUB(jakieś wyrażenie jest prawdziwe; jakieś inne wyrażenie jest prawdziwe); wartość jeśli prawda; wartość jeśli fałsz)
NIE — =JEŻELI(NIE(jakieś wyrażenie jest prawdziwe); wartość jeśli prawda; wartość jeśli fałsz)

Przykłady

Poniżej przedstawiono przykłady typowych zagnieżdżonych instrukcji JEŻELI(ORAZ()), JEŻELI(LUB()) i JEŻELI(NIE()) w programie Excel. Funkcje ORAZ i LUB mogą obsługiwać do 255 odrębnych warunków, ale używanie więcej niż kilku warunków nie jest dobrym rozwiązaniem, ponieważ skomplikowane, zagnieżdżone formuły są trudne do utworzenia, testowania i obsługiwania. Funkcja NIE przyjmuje tylko jeden warunek.

Oto formuły zapisane zgodnie z ich logiką:

Formuła	Opis
=JEŻELI(ORAZ(A2>0;B2<100);PRAWDA;FAŁSZ)	JEŻELI wartość komórki A2 (25) jest większa niż 0 ORAZ wartość komórki B2 (75) jest mniejsza niż 100, zwróć wartość PRAWDA, w przeciwnym razie zwróć wartość FAŁSZ. W tym przypadku oba warunki są spełnione, więc zwracana jest wartość PRAWDA.
=JEŻELI(ORAZ(A3="Czerwony";B3="Zielony");PRAWDA;FAŁSZ)	Jeśli wartość komórki A3 („Niebieski”) równa się „Czerwony” ORAZ wartość komórki B3 („Zielony”) równa się „Zielony”, zwróć wartość PRAWDA, w przeciwnym razie zwróć wartość FAŁSZ. W tym przypadku tylko pierwszy warunek jest spełniony, więc jest zwracana wartość FAŁSZ.
=JEŻELI(LUB (A4>0;B4<50);PRAWDA;FAŁSZ)	JEŻELI wartość komórki A4 (25) jest większa niż 0 LUB wartość komórki B4 (75) jest mniejsza niż 50, zwróć wartość PRAWDA, w przeciwnym razie zwróć wartość FAŁSZ. W tym przypadku tylko pierwszy warunek ma wartość PRAWDA, ale ponieważ funkcja LUB wymaga tylko jednego argumentu o wartości prawdziwej, formuła zwraca wartość PRAWDA.
=JEŻELI(LUB(A5="Czerwony";B5="Zielony");PRAWDA;FAŁSZ)	JEŻELI wartość komórki A5 („Niebieski”) równa się „Czerwony” LUB wartość komórki B5 („Zielony”) równa się „Zielony”, zwróć wartość PRAWDA, w przeciwnym razie zwróć wartość FAŁSZ. W tym przypadku drugi argument ma wartość prawdziwą, więc formuła zwraca wartość PRAWDA.
=JEŻELI(NIE(A6>50);PRAWDA;FAŁSZ)	JEŻELI wartość komórki A6 (25) NIE jest większa niż 50, zwróć wartość PRAWDA, w przeciwnym razie zwróć wartość FAŁSZ. W tym przypadku 25 nie jest większe niż 50, więc formuła zwraca wartość PRAWDA.
=JEŻELI(NIE(A7="Czerwony");PRAWDA;FAŁSZ)	JEŻELI wartość komórki A7 („Niebieski”) NIE równa się „Czerwony”, zwróć wartość PRAWDA, w przeciwnym razie zwróć wartość FAŁSZ.

Zauważ, że we wszystkich powyższych przykładach za warunkami znajdują się nawiasy zamykające. Pozostałe argumenty prawda/fałsz są częścią zewnętrznej instrukcji JEŻELI. Zwracane w przykładach wartości PRAWDA/FAŁSZ możesz też zastąpić wartościami tekstowymi lub liczbowymi.

Oto kilka przykładów użycia funkcji ORAZ, LUB i NIE do obliczania dat.

Przykłady użycia funkcji JEŻELI z funkcjami ORAZ, LUB i NIE do szacowania dat

Oto formuły zapisane zgodnie z ich logiką:

Formuła	Opis
=JEŻELI(A2>B2;PRAWDA;FAŁSZ)	JEŻELI wartość komórki A2 jest większa niż wartość komórki B2, zwróć wartość PRAWDA, w przeciwnym razie zwróć wartość FAŁSZ. W tym przypadku 03/12/14 jest większe niż 01/01/14, więc formuła zwraca wartość PRAWDA.
=JEŻELI(ORAZ(A3>B2;A3<C2);PRAWDA;FAŁSZ)	JEŻELI wartość komórki A3 jest większa niż wartość komórki B2 ORAZ wartość komórki A3 jest mniejsza niż wartość komórki C2, zwróć wartość PRAWDA, w przeciwnym razie zwróć wartość FAŁSZ. W tym przypadku oba argumenty mają wartość prawdziwą, więc formuła zwraca wartość PRAWDA.
=JEŻELI(LUB(A4>B2;A4<B2+60);PRAWDA;FAŁSZ)	JEŻELI wartość komórki A4 jest większa niż wartość komórki B2 LUB wartość komórki A4 jest mniejsza niż wartość komórki B2 + 60, zwróć wartość PRAWDA, w przeciwnym razie zwróć wartość FAŁSZ. W tym przypadku pierwszy argument ma wartość prawdziwą, ale drugi ma wartość fałszywą. Ponieważ funkcja LUB wymaga tylko jednego argumentu o wartości prawdziwej, formuła zwraca wartość PRAWDA. Jeśli użyjesz Kreatora Szacowanie formuły z karty Formuły, zobaczysz, w jaki sposób program Excel szacuje formułę.
=JEŻELI(NIE(A5>B2);PRAWDA;FAŁSZ)	JEŻELI wartość komórki A5 nie jest większa niż wartość komórki B2, zwróć wartość PRAWDA, w przeciwnym razie zwróć wartość FAŁSZ. W tym przypadku wartość komórki A5 jest większa niż wartość komórki B2, więc formuła zwraca wartość FAŁSZ.

Używanie funkcji ORAZ, LUB i NIE z formatowaniem warunkowym w programie Excel

W programie Excel można również użyć operatorów ORAZ, LUB i NIE, aby ustawić kryteria formatowania warunkowego za pomocą opcji formuły. W takim przypadku możesz pominąć funkcję JEŻELI i użyć samych funkcji ORAZ, LUB i NIE.

W programie Excel na karcie Narzędzia główne kliknij pozycję Formatowanie warunkowe > Nowa reguła. Następnie wybierz opcję „Użyj formuły do określenia komórek, które należy sformatować”, wprowadź formułę i zastosuj wybrany format.

Formatowanie warunkowe > Okno dialogowe Edytowanie reguły wyświetlające metodę formuły

Korzystając z wcześniejszego przykładu z datami, oto jak wyglądałyby te formuły.

Przykłady użycia funkcji ORAZ, LUB i NIE jako testów formatowania warunkowego

Formuła	Opis
=A2>B2	Jeśli wartość komórki A2 jest większa niż wartość komórki B2, sformatuj komórkę, w przeciwnym razie nic nie rób.
=ORAZ(A3>B2;A3<C2)	Jeśli wartość komórki A3 jest większa niż wartość komórki B2 ORAZ wartość komórki A3 jest mniejsza niż wartość komórki C2, sformatuj komórkę, w przeciwnym razie nic nie rób.
=LUB(A4>B2;A4<B2+60)	Jeśli wartość komórki A4 jest większa niż wartość komórki B2 LUB wartość komórki A4 jest mniejsza niż wartość komórki B2 plus 60 (dni), sformatuj komórkę, w przeciwnym razie nic nie rób.
=NIE(A5>B2)	Jeśli wartość komórki A5 NIE jest większa niż wartość komórki B2, sformatuj komórkę, w przeciwnym razie nic nie rób. W tym przypadku wartość komórki A5 jest większa niż wartość komórki B2, więc wynik zwróci wartość FAŁSZ. Gdyby zmienić formułę na =NIE(B2>A5), zwróciłaby ona wartość PRAWDA, a komórka zostałaby sformatowana.

Uwaga: Typowym błędem jest wprowadzenie formuły do formatowania warunkowego bez znaku równości (=). W takim przypadku zobaczysz, że w oknie dialogowym Formatowanie warunkowe zostanie dodany znak równości i cudzysłów do formuły — ="LUB(A4>B2;A4<B2+60)",więc musisz usunąć cudzysłowy, zanim formuła zareaguje prawidłowo.