Svojstvo „OpenArgs“

Odnosi se na

Određuje izraz niske koji navodi argument OpenArgs metoda OpenForm koji je otvorio obrazac. Čitanje i pisanje varijanta.

izraz.OpenArgs

expression Obavezno. Izraz koji daje jedan od objekata sa liste „Odnosi se na“.

Napomene

Ovo svojstvo je dostupno samo pomoću makro ili pomoću Visual Basic for Applications (VBA) koda sa metodom OpenForm objekta DoCmd. Ova postavka svojstva je samo za čitanje u svim prikazima.

Da biste koristili svojstvo OpenArgs, otvorite obrazac tako što ćete koristiti metod OpenForm objekta DoCmd i postavite argument OpenArgs na željeni izraz niske. Postavka svojstva OpenArgs može da se koristi u kodu za obrazac, kao što je u otvorenom procedura za obradu događaja. Takođe možete da uputite na postavku svojstva u makrou, kao što je otvoreni makro ili izraz, kao što je izraz koji postavlja svojstvo ControlSource za kontrola u obrascu.

Na primer, recimo da je obrazac koji ste otvorili kontinuirani obrazac liste klijenata. Ako želite da fokus pređe na određeni zapis klijenta kada se obrazac otvori, možete da podesite svojstvo OpenArgs na ime klijenta, a zatim da koristite radnju FindRecord u otvorenom makrou da biste premestili fokus na zapis za klijenta sa navedenim imenom.

Primer

Sledeći primer koristi svojstvo OpenArgs da biste otvorili obrazac „Zaposleni“ u određenom zapisu zaposlenih i pokazuje kako metod OpenForm podešava svojstvo OpenArgs. Ovu proceduru možete da pokrenete po potrebi – na primer, kada se desi događaj AfterUpdate za prilagođeni dijalog koji se koristi za unos novih informacija o zaposlenom.

Sub OpenToCallahan()
    DoCmd.OpenForm "Employees", acNormal, , , _
        acReadOnly, , "Callahan"
End Sub
Sub Form_Open(Cancel As Integer)
    Dim strEmployeeName As String
    ' If OpenArgs property contains employee name, find
    ' corresponding employee record and display it on 
    ' form. For example,if the OpenArgs property 
    ' contains "Callahan", move to first "Callahan" 
    ' record.
    strEmployeeName = Forms!Employees.OpenArgs
    If Len(strEmployeeName) > 0 Then
        DoCmd.GoToControl "LastName"
        DoCmd.FindRecord strEmployeeName, , True, , _
           True, , True
    End If
End Sub

Sledeći primer koristi metod FindFirst radi pronalaženja zaposlenog imenovanog u svojstvu OpenArgs.

Private Sub Form_Open(Cancel As Integer)
    If Not IsNull(Me.OpenArgs) Then
        Dim strEmployeeName As String
        strEmployeeName = Me.OpenArgs
        Dim RS As DAO.Recordset
        Set RS = Me.RecordsetClone
        RS.FindFirst "LastName = '" & _
            strEmployeeName & "'"
        If Not RS.NoMatch Then
            Me.Bookmark = RS.Bookmark
        End If
    End If
End Sub